Unterordner mit X Copy aus aktuellem Pfad in ein anzugebendes Laufwerk kopieren

[kiximek]

Guten Morgen,

 

ich möchte mittels einer Bat-Datei alle Ordner und Unterordner ohne Ihnhalt vom aktuellen Startpunkt auf eine USB-FEstplatte kopieren.

Den Pfad der USB-Platte soll man mittels Eingabe des Laufwerksbuchstaben angeben.

Ich habe mich an XCopy versucht, aber es funktioniert einfach nicht.

 

Vielleicht kann mir einer helfen?

[Visar]

Was genau hast du denn bislang versucht? Kannst du das mal zeigen?

[kiximek]

Ja klar:

 

:nochmal
echo.
@echo off 
echo Abbrechen mit Strg-C 
set /p zielort=Ziellaufwerk eingeben:
if "%zielort%"=="" goto nochmal
echo Laufwerk %Zielort% wurde ausgewaehlt.

ECHO Kopiervorgang starten? (j / n)
SET /p wahl=
For %%A in (J N) Do if /i '%wahl%'=='%%A' goto :Wahl%%A
Echo Ungueltige Antwort&Pause&Exit /B 1
Goto Ende
:WahlN
echo Vorgang abgebrochen!
goto Ende
:WahlJ
::xcopy .\  %Zielort%:\ /T /E /i
:Ende
pause

 

[Visar]

Goto. Argh. Und generell fürchterlich unübersichtlich.

Vielleicht solltest du das xcopy nicht mit :: auskommentieren. 🤔

Das unten funktioniert bei mir aber und würde zudem erlauben, in z.B. H:\foo\bar\xcopy statt nur nach H:\ zu kopieren. Dafür muss dann allerdings H: statt nur H als Ziellaufwerk angegeben werden. Naja. Verschmerzbar.

:BEGIN
@echo off 
echo.
echo MeinWunderbaresKopierScriptMitGoto
echo Abbrechen mit Strg+C
echo.
set /P zielort="Ziellaufwerk eingeben: "

if "%zielort%" == "" (
  goto BEGIN
) else (
  set zielort=%zielort%\
)
echo Laufwerk %zielort% wurde ausgewaehlt.
echo.

set /P wahl="Kopiervorgang starten? (j / n) "
for %%A in (J N) do (
  if /i '%wahl%' == '%%A' (
    goto :Wahl%%A
  )
)
echo Ungueltige Antwort
goto END

:WahlN
  echo Vorgang abgebrochen!
  goto END

:WahlJ
  echo Kopiervorgang gestartet
  echo Kopiere von %cd% nach %zielort%
  xcopy "%cd%\*"  %zielort% /T /E /i

:END
pause

Ansonsten: Never heard of Powershell? 😉

Bearbeitet 12. April 2020 von Visar
Ungewollte leere Zeile entfernt

[kiximek]

Hallo,

das sieht definitiv besser aus und funktioniert super.

Vielen Dank und Frohe Ostern...

 

[Mathias G.]

so rein interesse halber, wieso xcopy und nicht robocopy?