Batch-Datei, die Daten ausliest und in eine csv schreibt

[SySi2001]

könnte einer von euch den kompletten code hier mal posten? wäre sehr nett

[_Martin_]

Ich habe die Ausgabe in die CSV in eine Zeile geändert (das ist der Sinn einer CSV), wobei so eine Zeile dann so aussieht:

"2005-03-14";" 8:34";"2331615232"

Ausserdem findet keine Ausgabe auf dem Bildschirm mehr statt.

@echo off

REM zu überwachendes Laufwek auswählen:

REM ----------------------------------

set LW=d:\


REM einen Dir-Befehl ohne Tausender-Trennzeichen 

REM in die Datei C:\temp\dirausgabe.txt schreiben

REM -----------------------------------

dir %LW% /-C >>C:\temp\dirausgabe.txt


REM Variablen erzeugen und auf "0" setzen

REM -----------------------------------

SET groesse=0

SET groesseneu=0


REM Die Zeilen in c:\temp\dirausgabe.txt zählen 

REM (Variable groesseneu pro Zeile um 1 hochzählen)

REM ---------------------------------

for /f "tokens=*" %%b in (c:\temp\dirausgabe.txt) do (SET /A groesseneu+=1)


REM Variable groesseneu nochmal um 1 erhöhen

REM -----------------------------------------

SET /A groesseneu+=1


REM wieder ein Dir ohne Tausender-Trennzeichen, diesmal nur die Letzte Zeile in

REM die Datei C:\temp\groessedir.txt schreiben

REM ----------------------------------------------

dir %LW% /-C| more +%groesseneu% >> C:\temp\groessedir.txt


REM Aus der letzten zeile von "dir" nur die erste Zahl (Anazhl Bytes) auslesen

REM und in Datei C:\temp\beschneidung1.txt speichern.

REM ----------------------------------------------------------

FOR /F "tokens=2,3* delims=," %%i IN (C:\temp\groessedir.txt) DO (echo %%i >>C:\temp\beschneidung1.txt)


REM DIe Anzahl der Bytes in die Variable "groesse" einlesen

REM groesse = Bytes

REM -----------------------------------------------------------

FOR /F %%k IN (C:\temp\beschneidung1.txt) DO (SET groesse=%%k)


REM Temporäre Arbeitsdateien löschen.

REM ---------------------------------

del C:\temp\dirausgabe.txt

del C:\temp\groessedir.txt

del C:\temp\beschneidung1.txt


REM Das Datum, die Zeit und die Groesse (in Bytes) in CSV schreiben

REM ---------------------------------------------------------------

ECHO "%DATE:~9,4%-%DATE:~6,2%-%DATE:~3,2%";"%TIME:~0,5%";"%groesse%" >>CSV.csv

[SySi2001]

danke martin!

echt super...

kann man die batch auch umschreiben, dass sie mir sagt wieviel des plattenplatzes belegt ist und nicht frei?

falls es kein großer aufwand ist, könntest du das noch posten?

[Thombo]

das wird so ohne weiteres nicht gehen.

Noichmal eben fix erklärt, was die Datei überhaupt macht:

sie mach auf der angegebenen Platte einen dir Befehl,

als Ergebnis in dem dir Befehl steht ganz unten

"x Verzeichnisse 2.345.456.987 Byte frei"

Aus dem letzten Satz wird lediglich die Zahl (2345456987) ausgelesen.

In der ausgabe von dir steht nur drin, wieviel byte frei sind, nicht wieviel belegt ist.

[SySi2001]

ja, ich weiss, dass die freie kapa angezeigt wird.

also wäre es mit viel aufwand verbunden die bat umzuschreiben?

gruß

[Thombo]

wo willste denn die Freie Kapazität auslesen ?

[_Martin_]

Man könnte die Grösse des Laufwerks in der Batch Datei manuell angeben und dann später den belegten Speicher ausrechnen - wenn die Batch mit derart "grossen" Zahlen noch rechnen könnte.

Da sie das nicht kann (hab's auf einem 10 GB Laufwerk getestet) und ich auch keinen anderen Befehl kenne, der Infos über ein Laufwerk ausgibt, muss ich leider passen.

[Thombo]

ein chkdsk ohne Optionen gibt am Ende auch die Speicherplatze, sowie den verfügbaren Speicher an. Allerdings funktionier das auslesen nur, wenn kein Fehler gefunden wurde..... und die 3 Phasen vom chkdsk dauern auch ne Weile.