Formel in Excel erstellen

[Freak One]

Moin,Moin

ich will in einer datei die Spalte B+C prüfen, wenn dort ein "x" eingegeben ist soll

in Spalte E der Text "Kein Einsatz" erscheinen.

Siehe Bild

Vielleicht hat ja jemand einen Tip

[Enno]

wie soll das sein, wenn in beidem ein x ist soll dort stehen Kein Einsatz?

dann in Zelle E6

=WENN(UND($B6="x"; $C6="x");"Kein Einsatz";"")

einfügen.

Du kannst aber auch viel mehr machen.

Also schreib mal wann soll dort was stehen.

[Freak One]

Hallo enno,

wenn in den Spalten B und C ein Datum steht soll die differens in Monaten in Spalte E erscheinen,

wenn in Spalte B ein x ist und in Spalte C ein Datum steht soll "Erster Einsatz" in Spalte E erscheinen,

wenn in Spalte B und C ein x steht soll "Kein Einsatz" in Spalte E erscheinen.

[Enno]

=WENN(UND($B6="x"; $C6="x");"Kein Einsatz";WENN(UND($B6="x"; $C6<>"x");"Erster Einsatz";WENN(UND($B6<>"x"; $C6="x");"FEHLERHAFTE Eingabe!";"Monate Berechnen!")))

So damit macht er die punkte 2 und 3.

Und gibt ne Fehlermeldung aus, wenn B <> x und c = x

darf ja nach deiner definition nicht sein. oder?

welches fomrat haben die spalten b und c?

text? Zahl? oder was.

Dann kann man vielelciht auch die monatsberechnung machen.

im übrigen die Zeilen 10 und 11 wiedersprechen sich.

Spalten a / b / c sind identisch. Aber E ist unterschiedlich.

[Freak One]

Hallo Enno,

die Tabelle ist nur ein Entwurf, und meine Testumgebung für die Formeln.

Der momentane Inhalt hat nichts zu sagen.

Es soll so werden wie heute beschrieben.

Die Spalten sind Benutzerdefiniert und haben mm/jj.

[Enno]

=WENN(UND($B17="x"; $C17="x");"Kein Einsatz";WENN($B17="x";"Erster Einsatz";WENN(UND($B17<>"x"; $C17="x");"FEHLERHAFTE Eingabe!";ABRUNDEN((C17-B17)/30;0))))

Dann sollte die Formel so aussehen.

Es gibt bestimmt noch eleganntere Methoden die Monatsunterschied auszurechnen.

Ich hab mal einfach die Differenz genommen. Die ist leider in Tagen. Dann durch 30 geteilt. Dabei kommt aber immer ein ergebniss raus, das krumm ist. Also runden.

Passt sie dann so?

[Monty82]

Es gibt bestimmt noch eleganntere Methoden die Monatsunterschied auszurechnen.

=DATEDIF(A1;B1;"M")

[Enno]

ok also die zelle dann so:

=WENN(UND($B6="x"; $C6="x");"Kein Einsatz";WENN($B6="x";"Erster Einsatz";WENN(UND($B6<>"x"; $C6="x");"FEHLERHAFTE Eingabe!";DATEDIF($B6;$C6;"M"))))

Danke Monty das DATEDIF kannt eich jetzt auch noch nicht.

[Freak One]

Hallo Enno, Hallo Monty82,

ich danke euch beiden, es klappt hervorragend! :uli

Ich muß mich einfach mehr mit Excel beschäftigen.

Nochmals Danke