Rechnernamen aus Registry lesen

[dani1982]

Hallo,

kann mir eventuell Jemand sagen, wie ich in VB6 den Namen meines Rechners aus der Registry lese?

Vielen Dank schon mal im Vorraus.

Grüße, Dani (VB Anfängerin)

[DevHB]

Hi,

den Rechnernamen gibts per API:

' in ein Modul

Public Declare Function GetUserNameAPI Lib "advapi32.dll" Alias "GetUserNameA" _

                        (ByVal lpBuffer As String, _

                         nSize As Long _

) As Long


Public Function GetUserName( _

) As String


    Dim sBuffer As String, _

        sUser   As String


    Dim lBuffer As Long, _

        lRet    As Long


    lBuffer = 255

    sUser = VBA.Space$(lBuffer)

    lRet = GetUserNameAPI(sUser, lBuffer)

    If (lRet <> 0) Then

        GetUserName = VBA.Left$(sUser, lBuffer - 1)

        Exit Function

    End If

    GetUserName = VBA.Constants.vbNullString

End Function


'Aufruf:

Private Sub Form_Load

   Call MsgBox(GetUserName)

End Sub

[dani1982]

Hallo DevHB,

Danke für die schnelle Antwort, aber damit bekomme ich den Usernamen. Ich bräuchte den Rechnernamen. Geht das so ähnlich?

Gibt es da auch noch eine andere Möglichkeit, bei der ich dann den passenden RegistryKey angebe? Ich müsste nämlich auch noch überprüfen, welches Betriebssystem, also XP oder 2000, auf dem Rechner läuft (also: HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\CurrentVersion = 5.0/5.1)

Grüße,

Dani

[DevHB]

Ups, zu schnell gelesen:

' Modul

Private Const MAX_COMPUTERNAME_LENGTH = 15


Public Declare Function GetComputerNameAPI Lib "kernel32" Alias "GetComputerNameA" ( _

    ByVal lpBuffer As String, _

    nSize As Long _

) As Long


Public Function GetComputerName( _

) As String

    Dim sBuffer As String, _

        sName   As String


    Dim lResult As Long, _

        l       As Long


    l = MAX_COMPUTERNAME_LENGTH + 1

    sBuffer = VBA.Space$(l)

    lResult = GetComputerNameAPI(sBuffer, l)


    If (lResult = 1) Then

        sName = VBA.Left$(sBuffer, VBA.InStr(1, sBuffer, VBA.Chr$(0)) - 1)

        GetComputerName = sName

        Exit Function

    End If

    GetComputerName = VBA.Constants.vbNullString

End Function

Die Windowsversion kannst Du mit diesem Tip auslesen:

http://www.activevb.de/tipps/vb6tipps/tipp0129.html

[dani1982]

Cool, vielen Dank noch mal. Jetzt komm ich hier endlich weiter. :uli